//=============================================================================
//
// Project:   SharpImage
// Module:    shader-vmt-phong-enhance-simple.frag
// Language:  OpenGL Shading Language (GLSL)
// Author:    Dan Mueller
// Date:      $Date: 2007-09-26 15:20:34 +1000 (Wed, 26 Sep 2007) $
// Revision:  $Revision: 26 $
//
// Copyright (c) Queensland University of Technology (QUT) 2007.
// All rights reserved.
//
// This software is distributed WITHOUT ANY WARRANTY; without even
// the implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR
// PURPOSE.  See the copyright notices for more information.
//
//=============================================================================
uniform sampler3D sam3Tex0;    // Sampler for transfer function
uniform sampler3D sam3Tex1;    // Sampler for value image
uniform sampler3D sam3Tex2;    // Sampler for gradient image
uniform sampler3D sam3Tex3;    // Sampler for tags image
uniform float fSamplingRate;   // Current sampling rate
uniform float fNormalOffset;   // Offset for normal calculataions
uniform float fFactor1;	       // Enhancement factor
uniform float fFactor2;	       // Enhancement factor
uniform float fFactor3;	       // Enhancement factor

void main()
{
    // Interpolate images
    float value = vec4( texture3D(sam3Tex1, gl_TexCoord[1]) ).a;
    float grad  = vec4( texture3D(sam3Tex2, gl_TexCoord[2]) ).a;
    float tag   = vec4( texture3D(sam3Tex3, gl_TexCoord[3]) ).a;

    // Index transfer function
    const float LAYERS = 8.0;
    const float LAYER0 = 0.0 / ( LAYERS - 1.0 );
    const float LAYER1 = 1.0 / ( LAYERS - 1.0 );
    const float LAYER2 = 2.0 / ( LAYERS - 1.0 );
    const float LAYER3 = 3.0 / ( LAYERS - 1.0 );
    vec3 pos3TfAll  = vec3( value, 1.0-grad, LAYER0 );
    vec3 pos3TfTag1 = vec3( value, 1.0-grad, LAYER1 );
    vec3 pos3TfTag2 = vec3( value, 1.0-grad, LAYER2 );
    vec3 pos3TfTag3 = vec3( value, 1.0-grad, LAYER3 );
    vec4 val4TfBack = texture3D( sam3Tex0, pos3TfAll  );
    vec4 val4TfTag1 = texture3D( sam3Tex0, pos3TfTag1 );
    vec4 val4TfTag2 = texture3D( sam3Tex0, pos3TfTag2 );
    vec4 val4TfTag3 = texture3D( sam3Tex0, pos3TfTag3 );

    // Adjust alpha for sampling rate
    val4TfBack.a = 1.0 - pow( 1.0 - val4TfBack.a, 1.0 / fSamplingRate );
    val4TfTag1.a = 1.0 - pow( 1.0 - val4TfTag1.a, 1.0 / fSamplingRate );
    val4TfTag2.a = 1.0 - pow( 1.0 - val4TfTag2.a, 1.0 / fSamplingRate );
    val4TfTag3.a = 1.0 - pow( 1.0 - val4TfTag3.a, 1.0 / fSamplingRate );

    // Mix tags
    const float TAG0 = 0.0 / 255.0;
    const float TAG1 = 1.0 / 255.0;
    const float TAG2 = 2.0 / 255.0;
    const float TAG3 = 3.0 / 255.0;
    const float TAG4 = 4.0 / 255.0;
    vec4 val4Mix = float( tag == TAG0 ) * val4TfBack
                 + float( tag == TAG1 ) * val4TfTag1
                 + float( tag == TAG2 ) * val4TfTag2
                 + float( tag == TAG3 ) * val4TfTag3;
    if ( val4Mix.a <= 0.0 ) discard;

    // Compute the normal
    vec4 vec4G = vec4( 0.0 );
    for ( int i=0; i<3; i++ )
    {
        vec3 pos3L = vec3( gl_TexCoord[1] ); pos3L[i] -= fNormalOffset;
        vec3 pos3R = vec3( gl_TexCoord[1] ); pos3R[i] += fNormalOffset;
        float valL = texture3D( sam3Tex1, pos3L ).a;
        float valR = texture3D( sam3Tex1, pos3R ).a;
        vec4G[i] = (valL - valR) / 2.0;
    }
    vec4 vec4N = normalize( vec4G );

    // Compute light/viewing vector
    vec4 vec4L = vec4( 0.0, 0.0, -1.0, 0.0 );
    vec4L *= gl_ModelViewMatrix;
    vec4L = normalize( vec4(vec4L.x, vec4L.y, -vec4L.z, 0.0) );

    // Compute lighting terms
    float fLdotN = dot( vec4L, vec4N );
    vec4 vec4R = normalize( (2.0 * fLdotN * vec4N) - vec4L );
    float fRdotL = abs( dot(vec4R, vec4L) );

    // Compute and apply lighting
    gl_LightSourceParameters light = gl_LightSource[0];
    vec4 vec4A = light.ambient;
    vec4 vec4D = light.diffuse  * abs( fLdotN );
    vec4 vec4S = light.specular * pow( fRdotL, light.spotExponent );
    val4Mix.rgb *= vec3( vec4A + vec4D + vec4S );

    // Compute enhancement contributions
    vec4 black = vec4( 0.0, 0.0, 0.0, 1.0 );
    float silhouette = (fFactor1 <= 0.0) ? 0.0 : pow( 1.0 - abs( fLdotN ), fFactor1 );
    if ( silhouette > fFactor3 )
    {
        val4Mix.rgb = mix( black.rgb, val4Mix.rgb, fFactor2 );
        val4Mix.a *= silhouette;
    }

    // Apply lighting
    gl_FragColor = val4Mix;
}