//=============================================================================
//
// Project:   SharpImage
// Module:    shader-vm-enhance.frag
// Language:  OpenGL Shading Language (GLSL)
// Author:    Dan Mueller
// Date:      $Date: 2007-10-01 06:48:46 +1000 (Mon, 01 Oct 2007) $
// Revision:  $Revision: 27 $
//
// Copyright (c) Queensland University of Technology (QUT) 2007.
// All rights reserved.
//
// This software is distributed WITHOUT ANY WARRANTY; without even
// the implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR
// PURPOSE.  See the copyright notices for more information.
//
//=============================================================================
uniform sampler3D sam3Tex0;    // Sampler for transfer function
uniform sampler3D sam3Tex1;    // Sampler for value image
uniform sampler3D sam3Tex2;    // Sampler for gradient image
uniform float fSamplingRate;   // Current sampling rate
uniform float fNormalOffset;   // Offset for normal calculataions
uniform float fFactor1;	       // Enhancement factor
uniform float fFactor2;	       // Enhancement factor
uniform float fFactor3;	       // Enhancement factor

// Adjust the alpha value for the current sampling rate
float adjustAlphaForSamplingRate( float a )
{
    return 1.0 - pow( 1.0 - a,  1.0 / fSamplingRate );
}

// Compute the gradient using central differences
vec4 gradientFromCentralDifferences( )
{
    vec4 gradient = vec4( 0.0 );
    for ( int i=0; i<3; i++ )
    {
        vec3 pos3L = vec3( gl_TexCoord[1] ); pos3L[i] -= fNormalOffset;
        vec3 pos3R = vec3( gl_TexCoord[1] ); pos3R[i] += fNormalOffset;
        float valL = texture3D( sam3Tex1, pos3L ).a;
        float valR = texture3D( sam3Tex1, pos3R ).a;
        gradient[i] = (valL - valR) / 2.0;
    }
    return gradient;
}

// Compute the normal dot viewing vector
float computeNdotV( vec4 vec4N )
{
    vec4 vec4V = vec4( 0.0, 0.0, -1.0, 0.0 );
    vec4V *= gl_ModelViewMatrix;
    vec4V = normalize( vec4(vec4V.x, vec4V.y, -vec4V.z, 0.0) );
    return dot( vec4N, vec4V );
}

// Compute the silhouette enhancement
float enhanceSilhouette( vec4 vec4N )
{
    if (fFactor1 <= 0.0) return 0.0;
    return pow( 1.0 - abs( computeNdotV(vec4N) ), fFactor1 );
}

// Compute the boundary enhancement
float enhanceBoundary( float value )
{
    if (fFactor1 <= 0.0) return 1.0;
    return pow( value, fFactor1 );
}

void main()
{
    // Interpolate images
    float value = vec4( texture3D(sam3Tex1, gl_TexCoord[1]) ).a;
    float grad  = vec4( texture3D(sam3Tex2, gl_TexCoord[2]) ).a;

    // Interpolate transfer function
    vec3 pos3Tf = vec3( value, 1.0-grad, 0.0 );
    vec4 val4Tf = texture3D( sam3Tex0, pos3Tf );
    
    // Discard if no contribution
    if (val4Tf.a <= 0.0) discard;

    // Adjust alpha for sampling rate
    val4Tf.a = adjustAlphaForSamplingRate( val4Tf.a );

    // Compute the normal
    vec4 vec4G = gradientFromCentralDifferences( );
    vec4 vec4N = normalize( vec4G );

    // Apply enhancements
    vec4 black = vec4( 0.0, 0.0, 0.0, 1.0 );
    float silhouette = enhanceSilhouette( vec4N );
    //float boundary = enhanceBoundary( grad );
    if ( silhouette > fFactor3 )
    {
        val4Tf = mix( black, val4Tf, fFactor2 );
        val4Tf.a *= silhouette;
    }

    // Set color
    gl_FragColor = val4Tf;
}